JVM笔记 类文件结构与字节码指令

目标

本章主要了解一下 java字节码

也就是.class文件的类文件的接口

了解常见字节码指令

1 类文件结构（.class）

先来看以及简单的hello world 程序：

// HelloWorld.java
package cn.itcast.jvm.t5

public class HelloWorld{
	public static void main(String[] args){
		System.out.println("Hello World");
	}
}

执行 javac -parameters -d . HellowWorld.java // -parameters -d 保留参数名称信息

编译为 HelloWorld.class 后是这个样子的：

• 下面的1.1 - 2.1节就来分析这些字节码，额，如果觉得头疼（不行，我的头好痛啊，看到这些数字就头大），当然也可以直接跳过直接看2.2节

[root@localhost ~]# od -t xC HelloWorld.class
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07
0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29
0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e
0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63
0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01
0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63
0000160 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c 6f
0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16
0000220 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72
0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13
0000260 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69
0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61
0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46
0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64
0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e
0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64
0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74
0000440 63 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c
0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61
0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61
0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f
0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72
0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76
0000600 61 2f 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d
0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a
0000640 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b
0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01
0000700 00 07 00 08 00 01 00 09 00 00 00 2f 00 01 00 01
0000720 00 00 00 05 2a b7 00 01 b1 00 00 00 02 00 0a 00
0000740 00 00 06 00 01 00 00 00 04 00 0b 00 00 00 0c 00
0000760 01 00 00 00 05 00 0c 00 0d 00 00 00 09 00 0e 00
0001000 0f 00 02 00 09 00 00 00 37 00 02 00 01 00 00 00
0001020 09 b2 00 02 12 03 b6 00 04 b1 00 00 00 02 00 0a
0001040 00 00 00 0a 00 02 00 00 00 06 00 08 00 07 00 0b
0001060 00 00 00 0c 00 01 00 00 00 09 00 10 00 11 00 00
0001100 00 12 00 00 00 05 01 00 10 00 00 00 01 00 13 00
0001120 00 00 02 00 14

根据 JVM 规范，类文件结构如下

PS:u[数字] 表示字节数

ClassFile {
u4 magic; 											// 魔术
u2 minor_version;									// 小版本号
u2 major_version;									// 主版本号
u2 constant_pool_count;								// 常量池信息
cp_info constant_pool[constant_pool_count-1];		
u2 access_flags;									// 访问修饰，私有还是公共
u2 this_class;										// 类的包名 类名
u2 super_class;										// 父类信息
u2 interfaces_count;								// 接口信息
u2 interfaces[interfaces_count];					// 
u2 fields_count;									// 类中的成员变量信息
field_info fields[fields_count];
u2 methods_count;									// 类中的方法信息，成员方法等
method_info methods[methods_count];
u2 attributes_count;								// 类的附加信息
attribute_info attributes[attributes_count];
}

1.1 魔术

• 0~3 字节，表示它是否是【class】类型的文件

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

魔术用来表示这个文件是什么类型，这里ca fe ba be 表示这是一个java文件

1.2 版本

• 4~7 字节，表示类的版本 00 34（52） 表示是 Java 8

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

1.3 常量池

常量池参数表

Constant Type	Value
CONSTANT_Class	7
CONSTANT_Fieldref	9
CONSTANT_Methodref	10
CONSTANT_InterfaceMethodref	11
CONSTANT_String	8
CONSTANT_Integer	3
CONSTANT_Float	4
CONSTANT_Long	5
CONSTANT_Double	6
CONSTANT_NameAndType	12
CONSTANT_Utf8	1
CONSTANT_MethodHandle	15
CONSTANT_MethodType	16
CONSTANT_InvokeDynamic	18

8~9 字节，表示常量池长度

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

00 23 （35） 表示常量池有 #1~#34项，注意 #0 项不计入，也没有值

• 第#1项

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

0a （10：CONSTANT_Methodref ）表示一个 Method 信息

00 06 （6 ）和 00 15（21） 表示它引用了常量池中 #6 和 #21 项来获得 这个方法的【所属类】和【方法名】

• 第#2项

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

09(9: CONSTANT_Fieldref ) 表示一个 Field 信息

00 16（22）和 00 17（23） 表示它引用了常量池中 #22 和 # 23 项,来获得这个成员变量的【所属类】和【成员变量名】

• 第#3项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

08(8: CONSTANT_String) 表示一个字符串常量名称00 18（24）表示它引用了常量池中 #24 项

• 第#4项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

0a (10:CONSTANT_Methodref )表示一个 Method 信息，

00 19（25） 和 00 1a（26） 表示它引用了常量池中 #25 和 #26 项来获得这个方法的【所属类】和【方法名】

• 第#5项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

07(7:CONSTANT_Class ) 表示一个 Class 信息，00 1b（27） 表示它引用了常量池中 #27 项

• 第#6项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

07 (7:CONSTANT_Class ) 表示一个 Class信息

00 1c（28） 表示它引用了常量池中 #28 项 ,也即 要查 28项就知道类名叫啥了

• 第#7项

0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

01 表示一个 utf8 串，

00 06 表示长度，

3c 69 6e 69 74 3e 是【 】

• 第#8项

0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

01 表示一个 utf8 串

00 03 表示长度

28 29 56 是【()V】其实就是表示无参、无返回值

• 第#9项

0000060 56 01 00 04 43 6f 64 6501 00 0f 4c 69 6e 65 4e

01 表示一个 utf8 串，

00 04 表示长度，

43 6f 64 65 是【Code】

• 第#10项

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63

01 表示一个utf8 串，00 0f（15） 表示长度，4c 69 6e 65 4e 75 6d 62 65 72 54 61 62 6c 65

是【LineNumberTable】

• 第#11项

0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63

0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01

01 表示一个 utf8 串，00 12（18） 表示长度，4c 6f 63 61 6c 56 61 72 69 61 62 6c 65 54 61

62 6c 65是【LocalVariableTable】

• 第#12项

0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01

0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63

01 表示一个 utf8 串，00 04 表示长度，74 68 69 73 是【this】

• 第#13项

0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63

0000160 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c 6f

0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16

01 表示一个 utf8 串，00 1d（29） 表示长度，是【Lcn/itcast/jvm/t5/HelloWorld;】

• 第#14项

0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16

01 表示一个 utf8 串，00 04 表示长度，74 68 69 73 是【main】

• 第#15项

0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16

0000220 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72

0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13

01 表示一个 utf8 串，00 16（22） 表示长度，是【([Ljava/lang/String;)V】其实就是参数为

字符串数组，无返回值

• 第#16项

0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13

01 表示一个 utf8 串，00 04 表示长度，是【args】

• 第#17项

0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13

0000260 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69

0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61

01 表示一个 utf8 串，00 13（19） 表示长度，是【[Ljava/lang/String;】

• 第#18项

0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61

0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46

01 表示一个 utf8 串，00 10（16） 表示长度，是【MethodParameters】

• 第#19项

0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46

0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64

01 表示一个 utf8 串，

00 0a（10） 表示长度，是【SourceFile】

• 第#20项

0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

01 表示一个 utf8 串，00 0f（15） 表示长度，是【HelloWorld.java】

• 第#21项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

0c 表示一个 【名+类型】，00 07 00 08 引用了常量池中 #7 #8 两项

• 第#22项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

07 表示一个 Class 信息，00 1d（29） 引用了常量池中#29 项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64

第#23项 0c 表示一个 【名+类型】，00 1e（30） 00 1f （31）引用了常量池中 #30 #31 两项

• 第#24项

0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64

01 表示一个 utf8 串

00 0b（15） 表示长度，

后面十五个字节翻译过过来是【hello world】

• 第#25项

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74

07 表示一个 Class 信息，00 20（32） 引用了常量池中 #32 项

• 第#26项

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74

0c 表示一个 【名+类型】，00 21（33） 00 22（34）引用了常量池中 #33 #34 两项

• 第#27项

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74

0000440 63 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c

0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61

01 表示一个 utf8 串，00 1b（27） 表示长度，是【cn/itcast/jvm/t5/HelloWorld】

• 第#28项

0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61

0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61

01 (1:CONSTANT_Utf8) 表示一个 utf8 串，

00 10（16） 表示长度，

6a 61 76 61 2f 6c 61 6e 67 2f 4f 62 6a 65 63 74 翻译成字符是【java/lang/Object】

• 第#29项

0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61

0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f

01 表示一个 utf8 串，00 10（16） 表示长度，是【java/lang/System】

• 第#30项

0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f

0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72

01 表示一个 utf8 串，00 03 表示长度，是【out】

• 第#31项

0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72

0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76

01 表示一个 utf8 串，00 15（21） 表示长度，是【Ljava/io/PrintStream;】

• 第#32项

0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76

0000600 61 2f 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d

01 表示一个 utf8 串，00 13（19） 表示长度，是【java/io/PrintStream】

• 第#33项

0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a

01 表示一个 utf8 串，00 07 表示长度，是【println】

• 第#34项

0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a

0000640 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

01 表示一个 utf8 串，00 15（21） 表示长度，是【(Ljava/lang/String;)V】

1.4 访问标识与继承信息

Flag Name	Value	Interpretation
ACC_PUBLIC	0x0001	Declared public ; may be accessed from outside its package.
ACC_FINAL	0x0010	Declared final ; no subclasses allowed.
ACC_SUPER	0x0020	Treat superclass methods specially when invoked by the invokespecial instruction.
ACC_INTERFACE	0x0200	invokespecial instruction.
ACC_ABSTRACT	0x0400	Declared abstract ; must not be instantiated.
ACC_SYNTHETIC	0x1000	Declared synthetic; not present in the source code.
ACC_ANNOTATION	0x2000	Declared as an annotation type.
ACC_ENUM	0x4000	Declared as an enum type.

21 表示该 class 是一个类，公共的 (20+1 : ACC_SUPER + ACC_PUBLIC )

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

05 表示根据常量池中 #5 找到本类全限定名( 是 cn/itcast/jvm/t5/HelloWorld )

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

06 表示根据常量池中 #6 找到父类全限定名（是 java/lang/Object）

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

表示接口的数量，本类为 0 （）

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

1.5 Field 信息（成员标量信息）

表示成员变量数量，本类为 0

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

FieldType	Type	Interpretation
B	byte	signed byte
C	char	Unicode character code point in the Basic Multilingual Plane,encoded with UTF-16
D	double	encoded with UTF-16
F	float	single-precision flfloating-point value
I	int	integer
J	long	long integer
L ClassName ;	reference	an instance of class ClassName
S	short	signed short
z	boolean	true or false
[	one array dimension	one array dimension

1.6 Method 信息

表示方法数量，本类为 2

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

一个方法由 访问修饰符，名称，参数描述，方法属性数量，方法属性组成

• 红色代表访问修饰符（本类中是 public）
• 蓝色代表引用了常量池 #07 项作为方法名称
• 绿色代表引用了常量池 #08 项作为方法参数描述

• 黄色代表方法属性数量，本方法是 1

• 红色代表方法属性

  • 00 09 表示引用了常量池 #09 项，发现是【Code】属性

  • 00 00 00 2f 表示此属性的长度是 47

  • 00 01 表示【操作数栈】最大深度

  • 00 01 表示【局部变量表】最大槽（slot）数00 00 00 05 表示字节码长度，本例是 5

  • 2a b7 00 01 b1 是字节码指令

  • 00 00 00 02 表示方法细节属性数量，本例是 2

  • 00 0a 表示引用了常量池 #10 项，发现是【LineNumberTable】属性

    • 00 00 00 06 表示此属性的总长度，本例是 6

    • 00 01 表示【LineNumberTable】长度

    • 00 00 表示【字节码】行号 00 04 表示【java 源码】行号

  • 00 0b 表示引用了常量池 #11 项，发现是【LocalVariableTable】属性

    • 00 00 00 0c 表示此属性的总长度，本例是 12

    • 00 01 表示【LocalVariableTable】长度

    • 00 00 表示局部变量生命周期开始，相对于字节码的偏移量

    • 00 05 表示局部变量覆盖的范围长度

    • 00 0c 表示局部变量名称，本例引用了常量池 #12 项，是【this】

    • 00 0d 表示局部变量的类型，本例引用了常量池 #13 项，是

      • 【Lcn/itcast/jvm/t5/HelloWorld;】

    • 00 00 表示局部变量占有的槽位（slot）编号，本例是 0

• 红色代表访问修饰符（本类中是 public static）

• 蓝色代表引用了常量池 #14 项作为方法名称

• 绿色代表引用了常量池 #15 项作为方法参数描述

• 黄色代表方法属性数量，本方法是 2

• 红色代表方法属性（属性1）

  • 00 09 表示引用了常量池 #09 项，发现是【Code】属性

  • 00 00 00 37 表示此属性的长度是 55

  • 00 02 表示【操作数栈】最大深度

  • 00 01 表示【局部变量表】最大槽（slot）数

  • 00 00 00 05 表示字节码长度，本例是 9

  • b2 00 02 12 03 b6 00 04 b1 是字节码指令

  • 00 00 00 02 表示方法细节属性数量，本例是 2

  • 00 0a 表示引用了常量池 #10 项，发现是【LineNumberTable】属性

    • 00 00 00 0a 表示此属性的总长度，本例是 10

    • 00 02 表示【LineNumberTable】长度

    • 00 00 表示【字节码】行号 00 06 表示【java 源码】行号

    • 00 08 表示【字节码】行号 00 07 表示【java 源码】行号

  • 00 0b 表示引用了常量池 #11 项，发现是【LocalVariableTable】属性

    • 00 00 00 0c 表示此属性的总长度，本例是 12

    • 00 01 表示【LocalVariableTable】长度00 00 表示局部变量生命周期开始，相对于字节码的偏移量

    • 00 09 表示局部变量覆盖的范围长度

    • 00 10 表示局部变量名称，本例引用了常量池 #16 项，是【args】

    • 00 11 表示局部变量的类型，本例引用了常量池 #17 项，是【[Ljava/lang/String;】

    • 00 00 表示局部变量占有的槽位（slot）编号，本例是 0

• 红色代表方法属性（属性2）

  • 00 12 表示引用了常量池 #18 项，发现是【MethodParameters】属性
    • 00 00 00 05 表示此属性的总长度，本例是 5
    • 01 参数数量
    • 00 10 表示引用了常量池 #16 项，是【args】
    • 00 00 访问修饰符

1.7 附加属性

• 00 01 表示附加属性数量
• 00 13 表示引用了常量池 #19 项，即【SourceFile】
• 00 00 00 02 表示此属性的长度
• 00 14 表示引用了常量池 #20 项，即【HelloWorld.java】

参考文献

https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-4.html

2. 字节码指令

2.1 入门：

参考 JVM指令集

接着上一节，研究一下两组字节码指令，一个是：

2a b7 00 01 b1

public cn.itcast.jvm.t5.HelloWorld(); 构造方法的字节码指令

• 2a => aload_0 加载 slot 0 的局部变量，即 this，做为下面的 invokespecial 构造方法调用的参数
• b7 => invokespecial 预备调用构造方法，哪个方法呢？
• 00 01 引用常量池中 #1 项，即【 Method java/lang/Object.”“:()V 】
• b1 表示返回

另一个是 public static void main(java.lang.String[]); 主方法的字节码指令

b2 00 02 12 03 b6 00 04 b1

1. b2 => getstatic 用来加载静态变量，哪个静态变量呢？
2. 00 02 引用常量池中 #2 项，即【Field java/lang/System.out:Ljava/io/PrintStream;】
3. 12=> ldc 加载参数，哪个参数呢？
4. 03 引用常量池中 #3 项，即 【String hello world】
5. b6 => invokevirtual 预备调用成员方法，哪个方法呢？
6. 00 04 引用常量池中 #4 项，即【Method java/io/PrintStream.println:(Ljava/lang/String;)V】
7. b1 表示返回

2.2 javap 工具

自己分析类文件结构太麻烦了（确实，能直接看字节码的人一定是大神或者神经病吧？），Oracle 提供了 javap 工具来反编译 class 文件

用法很简单就是 javap 跟上 .class 文件

-v: 输出类的详细信息，包括常量池信息等

如：

[root@localhost ~]# javap -v HelloWorld.class
Classfile /root/HelloWorld.class 
    Last modified Jul 7, 2019; size 597 bytes
    MD5 checksum 361dca1c3f4ae38644a9cd5060ac6dbc
    Compiled from "HelloWorld.java"
public class cn.itcast.jvm.t5.HelloWorld
    minor version: 0  
    major version: 52 // jdk8
    flags: ACC_PUBLIC, ACC_SUPER // public类
Constant pool: //常量池
    #1 = Methodref #6.#21 // java/lang/Object."<init>":()V 
        // 上述代码表示，第项是个方法引用 引用类型以及方法 以注释的形式放在了后面
    #2 = Fieldref #22.#23 //
    java/lang/System.out:Ljava/io/PrintStream;
    #3 = String #24 // hello world
    #4 = Methodref #25.#26 // java/io/PrintStream.println:
    (Ljava/lang/String;)V
    #5 = Class #27 // cn/itcast/jvm/t5/HelloWorld
    #6 = Class #28 // java/lang/Object
    #7 = Utf8 <init>
    #8 = Utf8 ()V
    #9 = Utf8 Code
    #10 = Utf8 LineNumberTable
    #11 = Utf8 LocalVariableTable
    #12 = Utf8 this
    #13 = Utf8 Lcn/itcast/jvm/t5/HelloWorld;
    #14 = Utf8 main
    #15 = Utf8 ([Ljava/lang/String;)V
    #16 = Utf8 args
    #17 = Utf8 [Ljava/lang/String;
    #18 = Utf8 MethodParameters
    #19 = Utf8 SourceFile
    #20 = Utf8 HelloWorld.java
    #21 = NameAndType #7:#8 // "<init>":()V
    #22 = Class #29 // java/lang/System
    #23 = NameAndType #30:#31 // out:Ljava/io/PrintStream;
    #24 = Utf8 hello world
    #25 = Class #32 // java/io/PrintStream
    #26 = NameAndType #33:#34 // println:(Ljava/lang/String;)V
    #27 = Utf8 cn/itcast/jvm/t5/HelloWorld
    #28 = Utf8 java/lang/Object
    #29 = Utf8 java/lang/System
    #30 = Utf8 out
    #31 = Utf8 Ljava/io/PrintStream;
    #32 = Utf8 java/io/PrintStream
    #33 = Utf8 println
    #34 = Utf8 (Ljava/lang/String;)V
{
    public cn.itcast.jvm.t5.HelloWorld(); //第一段构造方法
        descriptor: ()V
        flags: ACC_PUBLIC
        Code:
            stack=1, locals=1, args_size=1  // 最大操作栈深度 局部变量表长度 参数长度
                0: aload_0
                1: invokespecial #1 // Method java/lang/Object."<init>":()V
                4: return
            LineNumberTable: //方法特有属性
                line 4: 0	//4代表java代码的行号 0 表示字节码行号
            LocalVariableTable: //本地变量表
                Start Length Slot 	Name 		Signature
                    0     5     0 	this 		Lcn/itcast/jvm/t5/HelloWorld;
    		// 从字节码开始算起始范围 从 0-4 全是他的作用域
   
    public static void main(java.lang.String[]); // main方法
        descriptor: ([Ljava/lang/String;)V
        flags: ACC_PUBLIC, ACC_STATIC
        Code:
            stack=2, locals=1, args_size=1
                0: 	getstatic 		#2 			// Field java/lang/System.out:Ljava/io/PrintStream;
                3: ldc #3 // String hello world
                5: invokevirtual #4 // Method java/io/PrintStream.println:(Ljava/lang/String;)V
                8: return
            LineNumberTable:
                line 6: 0 //源代码中的第六行对应字节码中的0行
                line 7: 8 // 源代码中的第七行对应字节码的第8行
            LocalVariableTable:
                    Start 	Length 	Slot 	Name 	Signature
                        0 		9 		0 	args 	[Ljava/lang/String;
            MethodParameters: //方法的参数信息
                    Name 							Flags
                    args
}

2.3 图解方法执行流程

2.3.1 原始java代码

package cn.itcast.jvm.t3.bytecode;
/**
* 演示 字节码指令 和 操作数栈、常量池的关系
*/
public class Demo3_1 {
    public static void main(String[] args) {
        int a = 10;
        int b = Short.MAX_VALUE + 1;
        int c = a + b;
        System.out.println(c);
    }
}

2.3.2 编译后的字节码文件

[root@localhost ~]# javap -v Demo3_1.class

Classfile /root/Demo3_1.class

    Last modified Jul 7, 2019; size 665 bytes

    MD5 checksum a2c29a22421e218d4924d31e6990cfc5

    Compiled from "Demo3_1.java"

public class cn.itcast.jvm.t3.bytecode.Demo3_1

    minor version: 0

    major version: 52

    flags: ACC_PUBLIC, ACC_SUPER

Constant pool:

    \#1 = Methodref #7.#26 // java/lang/Object."<init>":()V

    \#2 = Class #27 // java/lang/Short

    \#3 = Integer 32768

    \#4 = Fieldref #28.#29 //java/lang/System.out:Ljava/io/PrintStream;

    \#5 = Methodref #30.#31 // java/io/PrintStream.println:(I)V

    \#6 = Class #32 // cn/itcast/jvm/t3/bytecode/Demo3_1

    \#7 = Class #33 // java/lang/Object

    \#8 = Utf8 <init>

    \#9 = Utf8 ()V

    \#10 = Utf8 Code

    \#11 = Utf8 LineNumberTable

    \#12 = Utf8 LocalVariableTable

    \#13 = Utf8 this

    \#14 = Utf8 Lcn/itcast/jvm/t3/bytecode/Demo3_1;

    \#15 = Utf8 main

    \#16 = Utf8 ([Ljava/lang/String;)V

    \#17 = Utf8 args

    \#18 = Utf8 [Ljava/lang/String;

    \#19 = Utf8 a#20 = Utf8 I

    \#21 = Utf8 b

    \#22 = Utf8 c

    \#23 = Utf8 MethodParameters

    \#24 = Utf8 SourceFile

    \#25 = Utf8 Demo3_1.java

    \#26 = NameAndType #8:#9 // "<init>":()V

    \#27 = Utf8 java/lang/Short

    \#28 = Class #34 // java/lang/System

    \#29 = NameAndType #35:#36 // out:Ljava/io/PrintStream;

    \#30 = Class #37 // java/io/PrintStream

    \#31 = NameAndType #38:#39 // println:(I)V

    \#32 = Utf8 cn/itcast/jvm/t3/bytecode/Demo3_1

    \#33 = Utf8 java/lang/Object

    \#34 = Utf8 java/lang/System

    \#35 = Utf8 out

    \#36 = Utf8 Ljava/io/PrintStream;

    \#37 = Utf8 java/io/PrintStream

    \#38 = Utf8 println

    \#39 = Utf8 (I)V

{

    public cn.itcast.jvm.t3.bytecode.Demo3_1();

        descriptor: ()V

        flags: ACC_PUBLIC

        Code:

            stack=1, locals=1, args_size=1

                0: aload_0

                1: invokespecial #1 // Method java/lang/Object."<init>":()V

                4: return

            LineNumberTable:

                line 6: 0

            LocalVariableTable:

                Start 	Length Slot Name 	Signature

                    0 		5 	0 	this 	Lcn/itcast/jvm/t3/bytecode/Demo3_1;

    public static void main(java.lang.String[]);

            descriptor: ([Ljava/lang/String;)V

            flags: ACC_PUBLIC, ACC_STATIC

            Code:

                stack=2, locals=4, args_size=1

                    0: bipush 10

                    2: istore_1

                    3: ldc #3 // int 32768

                    5: istore_2

                    6: iload_1

                    7: iload_2

                    8: iadd

                    9: istore_3

                    10: getstatic #4 // Field java/lang/System.out:Ljava/io/PrintStream;

                    13: iload_3

                    14: invokevirtual #5 // Method java/io/PrintStream.println:(I)V

                    17: return

                LineNumberTable:

                    line 8: 0

                    line 9: （stack=2，locals=4）

                    line 10: 6

                    line 11: 10

                    line 12: 17

                LocalVariableTable:

                    Start Length Slot 	Name 	Signature

                        0 	18 		0 	args 	[Ljava/lang/String;

                        3 	15 		1 	a 		I

                        6 	12 		2 	b 		I

                        10 	8 		3 	c 		I

            MethodParameters:

                        Name 					Flags

                        args

}

2.3.3 常量载入运行时常量池

什么是运行常量池？ 详见JVM笔记 内存结构一篇中介绍

运行时常量是起始属于方法区的一个组成部分，这里图中为了方便单独拎出来讲，当一个类被加载时，其编译后字节码文件常量池的部分会放进这里存储

• 1、 一些小数字不会存在常量池，会与方法的字节码指令存在一起
• 2、一旦数字大于short整数的范围（32767）就会存储在常量池中

2.3.4 方法字节码载入方法区

2.3.5 main 线程开始运行，分配栈帧内存

• 绿色表示局部变量表，蓝色表示操作数栈
• 字节码中的：stack=2, locals=4
  • local ：4 表示有四个局部变量 就划分了四个槽位
  • stack：2 表示划分了最大深度为2的操作数栈的部分，用于存储数据以及字节码指令

2.3.6 执行引擎开始执行方法区的字节码

bipush 10

• 将一个 byte 压入操作数栈（其长度会补齐 4 个字节，整数补0 负数补1），类似的指令还有

  sipush： 将一个 short 压入操作数栈（其长度会补齐 4 个字节）

  ldc ：将一个 int 压入操作数栈

  ldc2_w： 将一个 long 压入操作数栈（分两次压入，因为 long 是 8 个字节）

• 注意：这里小的数字都是和字节码指令存在一起，超过 short 范围的数字存入了常量池

istore_1

• 将操作数栈顶数据弹出，存入局部变量表的 slot 1

  

ldc #3

• 从常量池加载 #3 数据到操作数栈
• 注意 Short.MAX_VALUE 是 32767，所以 32768 = Short.MAX_VALUE + 1 实际是在编译期间计算好的

istore_2

iload_1

iload_2

iadd

istore_3

getstatic #4

iload_3

invokevirtual #5

• 找到常量池 #5 项
• 定位到方法区 java/io/PrintStream.println:(I)V 方法
• 生成新的栈帧（分配 locals、stack等）
• 传递参数，执行新栈帧中的字节码

• 执行完毕，弹出栈帧
• 清除 main 操作数栈内容

return

• 完成 main 方法调用，弹出 main 栈帧
• 程序结束

2.4 从字节码角度分析a++操作

目的：从字节码角度分析 a++ 相关题目

源码：

package cn.itcast.jvm.t3.bytecode;
/**
* 从字节码角度分析 a++ 相关题目
*/
public class Demo3_2 {
    public static void main(String[] args) {
        int a = 10;
        int b = a++ + ++a + a--;
        System.out.println(a);
        System.out.println(b);
    }
}

字节码：

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: (0x0009) ACC_PUBLIC, ACC_STATIC
    Code:
        stack=2, locals=3, args_size=1
        0: bipush 10
        2: istore_1
        3: iload_1
        4: iinc 1, 1
        7: iinc 1, 1
        10: iload_1
        11: iadd
        12: iload_1
        13: iinc 1, -1
        16: iadd
        17: istore_2
        18: getstatic #2 // Field
        java/lang/System.out:Ljava/io/PrintStream;
        21: iload_1
        22: invokevirtual #3 // Method
        java/io/PrintStream.println:(I)V
        25: getstatic #2 // Field
        java/lang/System.out:Ljava/io/PrintStream;
        28: iload_2
        29: invokevirtual #3 // Method
        java/io/PrintStream.println:(I)V
        32: return
    LineNumberTable:
        line 8: 0
        line 9: 3
        line 10: 18
        line 11: 25
        line 12: 32
    LocalVariableTable:
        Start 	Length 		Slot 	Name 	Signature
        	0 		33 		0 		args 	[Ljava/lang/String;
        	3 		30 		1 		a 		I	
        	18 		15 		2 		b 		I
                                             

分析：

• 注意 iinc 指令是直接在局部变量 slot 上进行运算
• a++ 和 ++a 的区别是先执行 iload 还是 先执行 iinc

bipush 10

istore_1

iload_1

iinc 1,1

iinc 1,1

iload_1

iadd

iload_1

iinc 1,-1

iadd

istore 2

2.5 条件判断指令

指令	助记符	含义
0x99	ifeq	判断是否 == 0
0x9a	ifne	判断是否 != 0
0x9b	iflflt	判断是否 < 0
0x9c	ifg	判断是否 >= 0
0x9d	ifgt	判断是否 > 0
0x9e	iflfle	判断是否 <= 0
0x9f	if_icmpeq	两个int是否 ==
0xa0	if_icmpne	两个int是否 !=
0xa1	if_icmplt	两个int是否 <
0xa2	if_icmpge	两个int是否 >=
0xa3	if_icmpgt	两个int是否 >
0xa4	if_icmple	两个int是否 <=
0xa5	if_acmpeq	两个引用是否 ==
0xa6	if_acmpne	两个引用是否 !=
0xc6	ifnull	判断是否 == null
0xc7	ifnonnull	判断是否 != null

几点说明：

• byte，short，char 都会按 int 比较，因为操作数栈都是 4 字节

  因为导入时会补，至于long呢？ 高四位第四位分开比

  Chapter 6. The Java Virtual Machine Instruction Set (oracle.com)

• goto 用来进行跳转到指定行号的字节码

源码：

public class Demo3_3 {
    public static void main(String[] args) {
        int a = 0;
        if(a == 0) {
            a = 10;
        } else {
            a = 20;
        }
    }
}

字节码：

0: iconst_0 //准备了一个0 （准备 0-5 是专门的；准备 6-65536在方法指令里；准备 65537以上在常量表）
1: istore_1 //将其放进局部变量表1
2: iload_1  // 读取 局部变量表1
3: ifne 12	// 如果不成立挑战到12行
6: bipush 10 //10 进栈
8: istore_1 // 讲 栈顶存进1号槽
9: goto 15 //跳15行
12: bipush 20 //20进栈
14: istore_1 // 存入1号槽
15: return

2.6 循环控制指令

其实循环控制还是前面介绍的那些指令，例如 while 循环：

public class Demo3_4 {
    public static void main(String[] args) {
        int a = 0;
        while (a < 10) {
            a++;
        }
    }
}

字节码是：

0: iconst_0
1: istore_1
2: iload_1
3: bipush 10
5: if_icmpge 14
8: iinc 1, 1
11: goto 2
14: return

for 循环：

public class Demo3_6 {

    public static void main(String[] args) {

        for (int i = 0; i < 10; i++) {

        }

    }

}

字节码：

0: iconst_0
1: istore_1
2: iload_1
3: bipush 10
5: if_icmpge 14
8: iinc 1, 1
11: goto 2
14: return

比较 while 和 for 的字节码，你发现它们是一模一样的，殊途也能同归😊

2.7 分析

从字节码角度分析，下列代码运行的结果:

public class Demo3_6_1 {
    public static void main(String[] args) {
        int i = 0;
        int x = 0;
        while (i < 10) {
            x = x++; 
            i++;
        }
        System.out.println(x); // 结果是 0
    }
}

分析：虽然先x++ iinc 导致局部变量表中的自增了，但是，右面的赋值操作却是将操作数栈中x的原始值0 重新放进了局部变量表，导致x的结果还是0；

2.8 构造方法

1） <cinit>()V (整个类的构造方法)

public class Demo3_8_1 {
    static int i = 10;
    static {
        i = 20;
    }
    static {
        i = 30;
    }
}

编译器会按从上至下的顺序，收集所有 static 静态代码块和静态成员赋值的代码，合并为一个特殊的方

法<cinit>()V ：

0: bipush 10
2: putstatic #2 // Field i:I
5: bipush 20
7: putstatic #2 // Field i:I
10: bipush 30
12: putstatic #2 // Field i:I
15: return

<cinit>()V 方法会在类加载的初始化阶段被调用

2） <init>()V （每个实例对象的构造方法）

public class Demo3_8_2 {
    private String a = "s1";
    {
        b = 20;
    }
    private int b = 10;
    {
        a = "s2";
    }
    public Demo3_8_2(String a, int b) {
        this.a = a;
        this.b = b;
    }
    public static void main(String[] args) {
        Demo3_8_2 d = new Demo3_8_2("s3", 30);
        System.out.println(d.a);
        System.out.println(d.b);
    }
}

编译器会按从上至下的顺序，收集所有 {} 代码块和成员变量赋值的代码，形成新的构造方法，但原始构

造方法内的代码总是在最后

public cn.itcast.jvm.t3.bytecode.Demo3_8_2(java.lang.String, int); //执行main函数时 里面的构造方法
    descriptor: (Ljava/lang/String;I)V
    flags: ACC_PUBLIC
    Code:
        stack=2, locals=3, args_size=3
        0: aload_0
            // 相当于把 this 加载入栈
        1: invokespecial #1 // super.<init>()V
            // 调用父类的构造方法 Object类
        4: aload_0
            // 把this加载
        5: ldc #2 // <- "s1"
            // 加载 "s1"
        7: putfield #3 // -> this.a
            // 把"s1" 赋值给 this.a
        10: aload_0
            // 加载 this
        11: bipush 20 // <- 20
            // 操作数在放一个 20
        13: putfield #4 // -> this.b
            // 把20 付给 this.b
        16: aload_0
        17: bipush 10 // <- 10
        19: putfield #4 // -> this.b
        22: aload_0
        23: ldc #5 // <- "s2"
        25: putfield #3 // -> this.a
            
            // 上面就是相当于新的构造方法里面从上至下收集所有 {} 代码块和成员变量赋值的代码，产生默认值
            // 后面才会执行“原本”的构造方法里面应该执行的内容
        28: aload_0 // 		-------------旧构造方法--------------
        29: aload_1 // <- slot 1(a) "s3" 						|
        30: putfield #3 // -> this.a 							|
        33: aload_0 											|
        34: iload_2 // <- slot 2(b) 30 							|
        35: putfield #4 // -> this.b 		-------------------
        38: return
    LineNumberTable: ...
    LocalVariableTable:
        Start 	Length 		Slot 	Name 	Signature
        	0 		39 		0 		this 	Lcn/itcast/jvm/t3/bytecode/Demo3_8_2;
        	0 		39 		1 		a 		Ljava/lang/String;
        	0 		39 		2 		b 		I
MethodParameters: ...

所以，JVM在执行构造方法时并非直接进入构造方法，而是行程了一个新的构造方法， 他会按照从上到下的顺序收集所有 {} 代码块和成员变量赋值的代码（这里忽略的声明必须在前，因为声明早就放在了 方法区的常量池中记录了 ），而将 原本构造方法里面的代码放在了最后面

2.9 方法调用

看一下几种不同的方法调用对应的字节码指令

public class Demo3_9 {
    public Demo3_9() { }
    private void test1() { }
    private final void test2() { }
    public void test3() { }
    public static void test4() { }
    public static void main(String[] args) {
        Demo3_9 d = new Demo3_9();
        d.test1();
        d.test2();
        d.test3();
        d.test4();
        Demo3_9.test4();
    }
}

字节码

0: new #2 // class cn/itcast/jvm/t3/bytecode/Demo3_9
3: dup
4: invokespecial #3 // Method "<init>":()V 
    // 构造方法
7: astore_1
8: aload_1
9: invokespecial #4 // Method test1:()V
    // 私有方法
12: aload_1
13: invokespecial #5 // Method test2:()V
    // final
16: aload_1
17: invokevirtual #6 // Method test3:()V
    // public ：注意其他方法在运行前就能确定调用的时那个方法，只有普通的public 只有在运行时才知道调用的是哪个对象的方法，也叫动态绑定
20: aload_1
21: pop
22: invokestatic #7 // Method test4:()V
    // static
25: invokestatic #7 // Method test4:()V
    // static 直接用静态方法相比于 调用成员的静态方法20-22 多了两个无用指令（20 21） 哈哈哈哈 
    // 因为最终锁定 的方法还是唯一的静态方法，所以相当于脱裤子放屁
28: return

重载的方法是静态绑定的，重写的方法是动态绑定的（多态的原理），康师傅java，ppt中的一句话（某个大神说的）：不要犯傻，只要不是动态绑定他就不是多态

具体执行流程

• new 是创建【对象】，给对象分配堆内存，执行成功会将【对象引用】压入操作数栈
• dup 是赋值操作数栈栈顶的内容，本例即为【对象引用】，为什么需要两份引用呢，一个是要配合 invokespecial 调用该对象的构造方法 “<init>”:()V （会消耗掉栈顶一个引用），另一个要配合 astore_1 赋值给局部变量
• 注意 new 对象这个操作包括了 new 和 dup 两个步骤

• 最终方法（final），私有方法（private），构造方法都是由 invokespecial 指令来调用，属于静态绑定普通成员方法是由 invokevirtual 调用，属于动态绑定，即支持多态
• 成员方法与静态方法调用的另一个区别是，执行方法前是否需要【对象引用】
• 比较有意思的是 d.test4(); 是通过【对象引用】调用一个静态方法，可以看到在调用
• invokestatic 之前执行了 pop 指令，把【对象引用】从操作数栈弹掉了😂
• 还有一个执行 invokespecial 的情况是通过 super 调用父类方法

2.10 多态的原理

package cn.itcast.jvm.t3.bytecode;
import java.io.IOException;
/**
* 演示多态原理，注意加上下面的 JVM 参数，禁用指针压缩
* -XX:-UseCompressedOops -XX:-UseCompressedClassPointers
*/
public class Demo3_10 {
    public static void test(Animal animal) {
        animal.eat();
        System.out.println(animal.toString());
    }
    public static void main(String[] args) throws IOException {
        test(new Cat());
        test(new Dog());
        System.in.read();
    }
}



abstract class Animal {
    public abstract void eat();
    @Override
    public String toString() {
        return "我是" + this.getClass().getSimpleName();
    }
}
class Dog extends Animal {
    @Override
    public void eat() {
        System.out.println("啃骨头");
	}
}
class Cat extends Animal {
    @Override
    public void eat() {
        System.out.println("吃鱼");
    }
}

借助虚拟机工具HSDB 可以看到底层的内存状态

1）运行代码

​ 停在 System.in.read() 方法上，这时运行 jps 获取进程 id

2）运行HSDB 工具

进入 JDK 安装目录，执行

java -cp ./lib/sa-jdi.jar sun.jvm.hotspot.HSDB

进入图形界面 atach 进程 id

3）查找某个对象

打开 Tools -> Find Object By Query

输入 select d from cn.itcast.jvm.t3.bytecode.Dog d 点击 Execute 执行

4）查看对象内存结构
点击超链接可以看到对象的内存结构，此对象没有任何属性，因此只有对象头的 16 字节，前 8 字节是
MarkWord，后 8 字节就是对象的 Class 指针但目前看不到它的实际地址

• 底层都是C++结构
• 对象头一共16个字节
• 前八个字节为对象的markword 包含了对象的哈希码 以及将来加锁时的所标记
• 后面八个字节表示类型指针

5）查看对象 Class 的内存地址
可以通过 Windows -> Console 进入命令行模式，执行

mem 0x00000001299b4978 2

mem 有两个参数，参数 1 是对象地址，参数 2 是查看 2 行（即 16 字节）结果中第二行 0x000000001b7d4028 即为 Class 的内存地址

6）查看类的 vtable

方法1：Alt+R 进入 Inspector 工具，输入刚才的 Class 内存地址，看到如下界面

方法2：或者 Tools -> Class Browser 输入 Dog 查找，可以得到相同的结果

无论通过哪种方法，都可以找到 Dog Class 的 vtable 长度为 6，意思就是 Dog 类有 6 个虚方法（多态

相关的，fifinal，static 不会列入）

那么这 6 个方法都是谁呢？从 Class 的起始地址开始算，偏移 0x1b8 就是 vtable （虚方法表，这个类的静态方法 final方法等不在这个表中,也即虚方法表和对象实例一同放在堆内存）的起始地址，进行计

算得到：

 0x000000001b7d4028
				1b8 +
---------------------
 0x000000001b7d41e0

通过 Windows -> Console 进入命令行模式，执行

mem 0x000000001b7d41e0 6
0x000000001b7d41e0: 0x000000001b3d1b10
0x000000001b7d41e8: 0x000000001b3d15e8
0x000000001b7d41f0: 0x000000001b7d35e8
0x000000001b7d41f8: 0x000000001b3d1540
0x000000001b7d4200: 0x000000001b3d1678
0x000000001b7d4208: 0x000000001b7d3fa8

就得到了 6 个虚方法的入口地址

7）验证方法地址

通过 Tools -> Class Browser 查看每个类的方法定义，比较可知

Dog - public void eat() @0x000000001b7d3fa8
Animal - public java.lang.String toString() @0x000000001b7d35e8;
Object - protected void finalize() @0x000000001b3d1b10;
Object - public boolean equals(java.lang.Object) @0x000000001b3d15e8;
Object - public native int hashCode() @0x000000001b3d1540;
Object - protected native java.lang.Object clone() @0x000000001b3d1678;

对号入座，发现

eat() 方法是 Dog 类自己的
toString() 方法是继承 String 类的
finalize() ，equals()，hashCode()，clone() 都是继承 Object 类的

8）小结

当执行 invokevirtual 指令时，

1. 先通过栈帧中的对象引用找到对象
2. 分析对象头，找到对象的实际 Class
3. Class 结构中有 vtable，它在类加载的链接阶段就已经根据方法的重写规则生成好了
4. 查表得到方法的具体地址
5. 执行方法的字节码
6. 从这步骤看，查找虚方法表有点繁琐，性能有点差，后续JVM也对查找方法进行了优化，缓存方法

2.11 异常处理

try-catch

public class Demo3_11_1 {
public static void main(String[] args) {
    int i = 0;
        try {
            i = 10;
        } catch (Exception e) {
            i = 20;
        }
    }
}

注意

为了抓住重点，下面的字节码省略了不重要的部分

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=1, locals=3, args_size=1
            0: iconst_0
            1: istore_1
            2: bipush 10
            4: istore_1
            5: goto 12
            8: astore_2
            9: bipush 20
            11: istore_1
            12: return
    Exception table:
        from   to  target  type
            2   5      8   Class java/lang/Exception
    LineNumberTable: ...
    LocalVariableTable:
        Start Length Slot Name Signature
            9     3   2   e    Ljava/lang/Exception;
            0    13   0   args [Ljava/lang/String;
            2    11   1   i    I
    StackMapTable: ...
    MethodParameters: ...
}

可以看到多出来一个 Exception table 的结构，[from, to) 是前闭后开的检测范围，一旦这个范围

内的字节码执行出现异常，则通过 type 匹配异常类型，如果一致，进入 target 所指示行号

8 行的字节码指令 astore_2 是将异常对象引用存入局部变量表的 slot 2 位置

多个 single-catch 块的情况

public class Demo3_11_2 {
    public static void main(String[] args) {
        int i = 0;
        try {
            因为异常出现时，只能进入 Exception table 中一个分支，所以局部变量表 slot 2 位置被共用
            multi-catch 的情况
            i = 10;
        } catch (ArithmeticException e) {
            i = 30;
        } catch (NullPointerException e) {
            i = 40;
        } catch (Exception e) {
            i = 50;
        }
    }
}

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=1, locals=3, args_size=1
            0: iconst_0
            1: istore_1
            2: bipush 10
            4: istore_1
            5: goto 26
            8: astore_2
            9: bipush 30
            11: istore_1
            12: goto 26
            15: astore_2
            16: bipush 40
            18: istore_1
            19: goto 26
            22: astore_2
            23: bipush 50
            25: istore_1
            26: return
        Exception table:
            	from 	to 	target 	type
            	2 		5 	8 		Class java/lang/ArithmeticException
            	2 		5 	15 		Class java/lang/NullPointerException
            	2 		5 	22 		Class java/lang/Exception
        LineNumberTable: ...
        LocalVariableTable:
            Start 	Length 	Slot 	Name 	Signature
            9 		3 		2 		e 		Ljava/lang/ArithmeticException;
            16 		3 		2 		e 		Ljava/lang/NullPointerException;
            23 		3 		2 		e 		Ljava/lang/Exception;
            0 		27 		0 		args 	[Ljava/lang/String;
            2 		25 		1 		i 		I
        StackMapTable: ...
        MethodParameters: ...

• 因为异常出现时，只能进入 Exception table 中一个分支，所以局部变量表 slot 2 位置被共用

multi-catch 的情况

public class Demo3_11_3 {

public static void main(String[] args) {
    try {
        Method test = Demo3_11_3.class.getMethod("test");
        test.invoke(null);
    } catch (NoSuchMethodException | IllegalAccessException |
        InvocationTargetException e) {
            e.printStackTrace();
    	}
    }
    public static void test() {
        System.out.println("ok");
    }
}

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=3, locals=2, args_size=1
            0: ldc #2
            2: ldc #3
            4: iconst_0
            5: anewarray #4
            8: invokevirtual #5
            11: astore_1
            12: aload_1
            13: aconst_null
            14: iconst_0
            15: anewarray #6
            18: invokevirtual #7
            21: pop
            22: goto 30
            25: astore_1
            26: aload_1
            27: invokevirtual #11 // e.printStackTrace:()V
            30: return
        Exception table:
            from 	to 	target 	type
            0 		22 	25 		Class java/lang/NoSuchMethodException
            0 		22 	25 		Class java/lang/IllegalAccessException
            0 		22 	25 		Class java/lang/reflect/InvocationTargetException
        LineNumberTable: ...
        LocalVariableTable:
            Start Length Slot Name 	Signature
            12 		10 		1 test 	Ljava/lang/reflect/Method;
            26 		4 		1 e 	Ljava/lang/ReflectiveOperationException;
            0 		31 		0 args 	[Ljava/lang/String;
        StackMapTable: ...
        MethodParameters: ...

finally

public class Demo3_11_4 {
    public static void main(String[] args) {
        int i = 0;
        try {
            i = 10;
        } catch (Exception e) {
            i = 20;
        } finally {
            i = 30;
        }
    }
}

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=1, locals=4, args_size=1
            0: iconst_0
            1: istore_1 		// 0 -> i
            2: bipush 10 		// try --------------------------------------
            4: istore_1 		// 10 -> i 									|
            5: bipush 30 		// finally 									|
            7: istore_1 		// 30 -> i 									|
            8: goto 27 			// return -----------------------------------
            11: astore_2 		// catch Exceptin -> e ----------------------
            12: bipush 20 		// 											|
            14: istore_1 		// 20 -> i 									|
            15: bipush 30 		// finally 									|
            17: istore_1 		// 30 -> i									|
            18: goto 27 		// return -----------------------------------
            21: astore_3 		// catch any -> slot 3 ----------------------
            22: bipush 30 		// finally 									|
            24: istore_1 		// 30 -> i 									|
            25: aload_3 		// <- slot 3 								|
            26: athrow 			// throw ------------------------------------
            27: return
        Exception table:
            from  to target type
            2     5    11 	Class java/lang/Exception
            2     5    21 	any // try块剩余的异常类型，比如 Error
            11    15   21 	any // catch块 异常类型，比如 Error
        LineNumberTable: ...
        LocalVariableTable:
            Start Length Slot Name Signature
            12 		3 		2 	e 		Ljava/lang/Exception;
            0 		28 		0 	args 	[Ljava/lang/String;
            2 		26 		1 	i 		I
        StackMapTable: ...
        MethodParameters: ...

可以看到 finally 中的代码被复制了 3 份，分别放入 try 流程，catch 流程以及 catch 剩余的异常类型流

程，并且在 分别在 try块，catch块增加了异常捕获（剩余）

2.12 练习 - finally 面试题

finally 出现了 return

下面的题目输出什么？

public class Demo3_12_2 {
    public static void main(String[] args) {
        int result = test();
        System.out.println(result);
    }
    public static int test() {
        try {
            return 10;
        } finally {
            return 20;
        }
    }
}

public static int test();
    descriptor: ()I
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=1, locals=2, args_size=0
            0: bipush 10 // <- 10 放入栈顶
            2: istore_0 // 10 -> slot 0 (从栈顶移除了)
            3: bipush 20 // <- 20 放入栈顶
            5: ireturn // 返回栈顶 int(20)
            6: astore_1 // catch any -> slot 1
            7: bipush 20 // <- 20 放入栈顶
            9: ireturn // 返回栈顶 int(20)
        Exception table:
            from to target type
             0   3    6    any
        LineNumberTable: ...
        StackMapTable: ...

• 由于 fifinally 中的 ireturn 被插入了所有可能的流程，因此返回结果肯定以 fifinally 的为准
• 至于字节码中第 2 行，似乎没啥用，且留个伏笔，看下个例子
• 跟上例中的 finally 相比，发现没有 athrow 了，这告诉我们：如果在 finally 中出现了 return，会吞掉异常(危险操作😱😱😱)，可以试一下下面的代码

public class Demo3_12_1 {
    public static void main(String[] args) {
        int result = test();
        System.out.println(result);
    }
    public static int test() {
        try {
            int i = 1/0;
            return 10;
        } finally {
            return 20;
        }
    }
}

发现没有报错直接返回20

finally 对返回值影响

public class Demo3_12_2 {
    public static void main(String[] args) {
        int result = test();
        System.out.println(result);
    }
    public static int test() {
        int i = 10;
        try {
            return i;
        } finally {
            i = 20;
        }
    }
}

public static int test();
    descriptor: ()I
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=1, locals=3, args_size=0
            0: bipush 10 // <- 10 放入栈顶
            2: istore_0 // 10 -> i
            3: iload_0 // <- i(10)
            4: istore_1 // 10 -> slot 1，暂存至 slot 1，目的是为了固定返回值
            5: bipush 20 // <- 20 放入栈顶
            7: istore_0 // 20 -> i
            8: iload_1 // <- slot 1(10) 载入 slot 1 暂存的值
            9: ireturn // 返回栈顶的 int(10)
            10: astore_2
            11: bipush 20
            13: istore_0
            14: aload_2
            15: athrow
        Exception table:
            from to target type
            3    5   10    any
        LineNumberTable: ...
        LocalVariableTable:
            Start Length Slot Name Signature
            3     13     0    i     I
        StackMapTable: ...

• finally 中不带return 语句的，不会把异常吞掉 有 athrow
• finally 中不带return 语句的 ，在 finally中修改局部变量的，并不会影响到真正的返回值，因为他会并且会暂存 局部变量 的返回值，为了固定返回值，即：如果在try块中return了，而在finally中对返回的变量做了变化，并不会影响到返回结果，

2.13 synchronized

public class Demo3_13 {
    public static void main(String[] args) {
        Object lock = new Object();
        synchronized (lock) {
            System.out.println("ok");
        }
    }
}

public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
        stack=2, locals=4, args_size=1
                  
           // 第一行代码       
            0: new #2 // new Object
            3: dup
            4: invokespecial #1 // invokespecial <init>:()V
            7: astore_1 // lock引用 -> lock
                  
          //         
            8: aload_1 // <- lock （synchronized开始）
                  // 把对象引用加载到操作数栈
            9: dup
                  // 复制，一个给monitorenter使用（加锁），另一个给monitorexit使用（解锁）
            10: astore_2 // lock引用 -> slot 2
            11: monitorenter // monitorenter(lock引用)
                  // 加锁
            12: getstatic #3 // <- System.out
            15: ldc #4 // <- "ok"
            17: invokevirtual #5 // invokevirtual println:(Ljava/lang/String;)V
            20: aload_2 // <- slot 2(lock引用)
            21: monitorexit // monitorexit(lock引用)
            22: goto 30
            25: astore_3 // any -> slot 3
            26: aload_2 // <- slot 2(lock引用)
            27: monitorexit // monitorexit(lock引用)
            28: aload_3
            29: athrow
            30: return
        Exception table:
            from to target type
            12  22  25    any
            25  28  25    any
                  // 无论是 获得锁后发生任何异常 还是 解锁失败（发生异常） 都会执行解锁操作，也即无论如何都要解锁
        LineNumberTable: ...
        LocalVariableTable:
            Start Length Slot Name Signature
              0      31   0   args [Ljava/lang/String;
              8      23   1   lock Ljava/lang/Object;
        StackMapTable: ...
        MethodParameters: ...

• 注意：方法级别的 synchronized 不会在字节码指令中有所体现